Max31865 HELP ME


+ Reply to Thread
Results 1 to 6 of 6

Thread: Max31865 HELP ME993 days old

  1. #1
    Junior Member cassio_franquini's Avatar
    Join Date
    Aug 2010
    Posts
    7
    Thumbs Up
    Received: 0
    Given: 0
    Total Downloaded
    1.16 GB

    0 Not allowed!

    Default Max31865 HELP ME

    Hello, can anyone help me? There are no more conditions for the Max31865 pt100, using pic16f876 with the commands below:

    Low CS
    SHOUT DI,CK,3,[$01\16] ' send command
    SHIn DO,CK,3,[resultADO\16] ' read data
    HIGH CS
    (sw SPI)

    What could be happening?




    Thank you

Attention

This valuable resource relies upon the very small amount of revenue generated by displaying online advertisements to our visitors.

The advertisements we display are relevant to this web site and your browsing history

Please consider supporting us by disabling your ad blocker.


Note: Some users have reported issues related to ad-blockers rendering parts of this wesite unusable,
where possible we will rectify the issues to enable you to use this resource with adblocking enabled.

If you can, please report issues in the forum area WebSite / Forum Issues


Thank you for your attention.

  • #2
    Fanatical Contributor top204's Avatar
    Join Date
    Feb 2002
    Posts
    3,481
    Thumbs Up
    Received: 315
    Given: 146
    Total Downloaded
    1.99 GB

    2 Not allowed!

    Default MAX31865 Demo Program

    Here's a simple program that will communicate with the MAX31865 chip and read its registers.

    Code:
    '
    ' Interface to a MAX31865 chip
    ' Written by Les Johnson for the Proton BASIC compiler
    '
        Include "Amicus18.inc"                          ' Configure the compiler to use a PIC18F25K20 device at 64MHz. i.e. an Amicus18 board
    
    $definecSensor_Wires 3                             ' PT100/1000 has 2 or 3 or 4 wire connection
    
    $define MAX31865_SDO_Pin PORTC.4                    ' Connects to the MAX31865 SDO pin
    $define MAX31865_SDI_Pin PORTC.5                    ' Connects to the MAX31865 SDI pin
    $define MAX31865_SCLK_Pin PORTC.3                   ' Connects to the MAX31865 SCLK pin
    $define MAX31865_CS_Pin PORTC.0                     ' Connects to the MAX31865 CS pin
    '
    ' Create variables
    '
        Dim MAX31865_bReg0 As Byte                      ' \
        Dim MAX31865_bReg1 As Byte                      ' |
        Dim MAX31865_bReg2 As Byte                      ' |
        Dim MAX31865_bReg3 As Byte                      ' | Hold the register values from the MAX31865 chip
        Dim MAX31865_bReg4 As Byte                      ' |
        Dim MAX31865_bReg5 As Byte                      ' |
        Dim MAX31865_bReg6 As Byte                      ' |
        Dim MAX31865_bReg7 As Byte                      ' /
    
        Dim MAX31865_bLoop As Byte                      ' The SPI loop counter
        Dim MAX31865_bData As Byte                      ' The SPI transfer variable
    
    '------------------------------------------------------------------------------------------------
        GoTo Main                                       ' Jump over the subroutines
    
    '-----------------------------------------------------------------------------
    
    $define MAX31865_Enable() Low MAX31865_CS_Pin       ' Enable the SPI interface
    $define MAX31865_Disable() High MAX31865_CS_Pin     ' Disable the SPI interface
    
    '-----------------------------------------------------------------------------
    ' Transmit and receive one byte using SPI mode 3 protocol
    ' Input     : WREG = 8-bit value to send
    '           : MAX31865_SCLK_Pin holds the Port.bit of the SPI Clock pin
    '           : MAX31865_SDI_Pin holds the Port.bit of the SPI Data out Pin
    ' Output    : WREG = 8-Bit value received
    ' Notes     : SCLK is idle-high, and bits are latched on SCLK rising
    '
    $define MAX31865_Com(pByteout) _SPI_Out3 pByteout
    
    _SPI_Out3 Macro pByteout \Byte
        #if(Prm_Count >= 1)
            #if((Prm_1 == Num8) || (Prm_1 == Num16) || (Prm_1 == Num32))
                Num_Wreg pByteout
            #else
                Byte_Wreg pByteout
            #endif
        #else
            WREG = 0
        #endif
        GoSub __SPI_Out3
        Return_WREG
    Endm
    
    __SPI_Out3:
        MAX31865_bData = WREG                           ' Transfer the WREG into MAX31865_bData
        For MAX31865_bLoop = 7 To 0 Step -1             ' Single byte SPI loop
            Low MAX31865_SCLK_Pin                       ' Pull SCLK low
            DelayMS 1
            MAX31865_SDI_Pin = MAX31865_bData.7         ' Put current outgoing bit on MAX31865_SDI_Pin
            MAX31865_bData = MAX31865_bData << 1        ' Shift next bit into MSB
            DelayMS 1
            Set MAX31865_SCLK_Pin                       ' Set SCLK high
            MAX31865_bData = MAX31865_bData | MAX31865_SDO_Pin  ' Capture current bit on MAX31865_SDO_Pin
            DelayMS 1
        Next
        WREG = MAX31865_bData                            ' Transfer MAX31865_bData into WREG
        Return
    
    '------------------------------------------------------------------------------------------------
    ' Configure the Interface to the MAX31865
    ' Input     : None
    ' Output    : None
    ' Notes     : None
    '
    $define MAX31865_Setup() GoSub _MAX31865_Setup
    
    _MAX31865_Setup:
        Low MAX31865_SCLK_Pin
        Output MAX31865_SDI_Pin
        Input MAX31865_SDO_Pin
        
        MAX31865_Enable()
        DelayMS 10    
        MAX31865_Com($80)                                   ' Point to the Configuration register ($00)
        $if cSensor_Wires = 2                               ' Are we using a 2 wire sensor?
            MAX31865_Com(% 11000010)
        $elseif cSensor_Wires = 3                           ' Are we using a 3 wire sensor?
            MAX31865_Com(% 11010010)
        $elseif cSensor_Wires = 4                           ' Are we using a 4 wire sensor?
            MAX31865_Com(% 11000010)
        $endif
        MAX31865_Disable()
        DelayMS 50
        Return
    
    '------------------------------------------------------------------------------------------------
    ' Read the registers from the MAX31865
    ' Input     : None
    ' Output    : MAX31865_bReg0, MAX31865_bReg1, MAX31865_bReg2, MAX31865_bReg3, MAX31865_bReg4, MAX31865_bReg5, MAX31865_bReg6, MAX31865_bReg7
    ' Notes     : None
    '
    $define MAX31865_Read() GoSub _MAX31865_Read
    
    _MAX31865_Read:
        MAX31865_Enable()
        MAX31865_Com(0)                                     ' Start reading from address 0
        MAX31865_bReg0 = MAX31865_Com(0)                    ' \
        MAX31865_bReg1 = MAX31865_Com(0)                    ' |
        MAX31865_bReg2 = MAX31865_Com(0)                    ' |
        MAX31865_bReg3 = MAX31865_Com(0)                    ' | Read all the 8 registers
        MAX31865_bReg4 = MAX31865_Com(0)                    ' |
        MAX31865_bReg5 = MAX31865_Com(0)                    ' |
        MAX31865_bReg6 = MAX31865_Com(0)                    ' |
        MAX31865_bReg7 = MAX31865_Com(0)                    ' /
        MAX31865_Disable()
        Return
    
    '------------------------------------------------------------------------------------------------
    ' Transmit the register values via USART1
    ' Input     : MAX31865_bReg0 to MAX31865_bReg7
    ' Output    : None
    ' Notes     : None
    '
    $define Display_Registers() GoSub _Display_Registers
    
    _Display_Registers:
        HRSOutLn "----------------------------------------------"
        HRSOutLn "Register values:"
        HRSOutLn "Reg0: Configuration = ", IBin8 MAX31865_bReg0
        HRSOutLn "Reg1: RTD MSBs = ", IHex MAX31865_bReg1
        HRSOutLn "Reg2: RTD LSBs = ", IHex MAX31865_bReg2
        HRSOutLn "Reg3: High Fault Treshold MSB = ", IHex MAX31865_bReg3
        HRSOutLn "Reg4: High Fault Treshold LSB = ", IHex MAX31865_bReg4
        HRSOutLn "Reg5: Low Fault Treshold MSB = ", IHex MAX31865_bReg5
        HRSOutLn "Reg6: Low Fault Treshold LSB = ", IHex MAX31865_bReg6
        HRSOutLn "Reg7: Fault Status = ", IBin8 MAX31865_bReg7
        Return
    
    '------------------------------------------------------------------------------------------------
    ' The main program loop starts here
    '
    Main:
        MAX31865_Setup()                                ' Setup the interface to the chip
    
        Do
            MAX31865_Read()                             ' Read all 8 registers
            Display_Registers()                         ' Serially transmit the register values
            DelayMS  1000 
        Loop
    I've written a full library for the MAX31865 to give temperatures and setup the chip etc, and this will be in the book I'm busy writing. It's in the "What's the Temperature" chapter, along with other devices and simple thermistor sensors, and a very simple diode sensor etc...
    Last edited by top204; 4th June 2017 at 08:12.

  • Attention

    This valuable resource relies upon the very small amount of revenue generated by displaying online advertisements to our visitors.

    The advertisements we display are relevant to this web site and your browsing history

    Please consider supporting us by disabling your ad blocker.


    Note: Some users have reported issues related to ad-blockers rendering parts of this wesite unusable,
    where possible we will rectify the issues to enable you to use this resource with adblocking enabled.

    If you can, please report issues in the forum area WebSite / Forum Issues


    Thank you for your attention.

  • #3
    Junior Member cassio_franquini's Avatar
    Join Date
    Aug 2010
    Posts
    7
    Thumbs Up
    Received: 0
    Given: 0
    Total Downloaded
    1.16 GB

    0 Not allowed!

    Default Re: MAX31865 Demo Program

    Ok, friend, thanks for quick reply, I have no experience with libs, how should I proceed to work the code, I tried to compile directly and did not compile, what should I do?




    thank you so much.

  • Attention

    This valuable resource relies upon the very small amount of revenue generated by displaying online advertisements to our visitors.

    The advertisements we display are relevant to this web site and your browsing history

    Please consider supporting us by disabling your ad blocker.


    Note: Some users have reported issues related to ad-blockers rendering parts of this wesite unusable,
    where possible we will rectify the issues to enable you to use this resource with adblocking enabled.

    If you can, please report issues in the forum area WebSite / Forum Issues


    Thank you for your attention.

  • #4
    Fanatical Contributor top204's Avatar
    Join Date
    Feb 2002
    Posts
    3,481
    Thumbs Up
    Received: 315
    Given: 146
    Total Downloaded
    1.99 GB

    0 Not allowed!

    Default Re: MAX31865 Demo Program

    With the latest compiler build from here:

    Compiler Update

    The above program will compile, because it is not a library, but a demo program.

  • Attention

    This valuable resource relies upon the very small amount of revenue generated by displaying online advertisements to our visitors.

    The advertisements we display are relevant to this web site and your browsing history

    Please consider supporting us by disabling your ad blocker.


    Note: Some users have reported issues related to ad-blockers rendering parts of this wesite unusable,
    where possible we will rectify the issues to enable you to use this resource with adblocking enabled.

    If you can, please report issues in the forum area WebSite / Forum Issues


    Thank you for your attention.

  • #5
    Junior Member cassio_franquini's Avatar
    Join Date
    Aug 2010
    Posts
    7
    Thumbs Up
    Received: 0
    Given: 0
    Total Downloaded
    1.16 GB

    0 Not allowed!

    Default Re: MAX31865 Demo Program

    Ok, my friend, it's not where I'm going wrong, I did not succeed, see my code ...

    Device 16F876A

    'config WDT_oN ,xt_OSC,LVP_OFF,PWRTE_ON,CP_ALL
    Config WDT_OFF,hs_OSC,LVP_OFF,PWRTE_ON,BODEN_OFF,CP_off

    'Include "versoes.bas"
    Remarks On
    Declare Xtal 20
    Declare LCD_DTPin PORTB.4
    Declare LCD_RSPin PORTB.2
    Declare LCD_ENPin PORTB.3
    Declare LCD_Interface 4
    Declare LCD_Lines 4
    Declare All_Digital = True

    CMCON=0x07 ' desabilita aos comparadores porta A

    '--------------------------------------------------------------------------------------------------------------
    CMCON = 7 ' desabilita aos comparadores porta A
    OPTION_REG.3=1 ' Direciona timer0 para WTG '
    OPTION_REG.0=1 '----------------------------------+
    OPTION_REG.1=1 ' Seleciona p prescaler *128 '
    OPTION_REG.2=1 '----------------------------------'
    ADCON1 = 7 ' Turn off ADC 0000011X
    SSPCON = %00000101
    All_Digital = TRUE
    Symbol TXD = PORTc.1
    trisc.5 = 1

    ' Symbol DQA = PORTA.2 : TRISA.2 = 1
    ' Symbol DQB = PORTA.1 : TRISA.1 = 1
    ' Symbol DQC = PORTA.0 : TRISA.0 = 1
    ' Symbol DQD = PORTA.3 : TRISA.3 = 1
    ' Symbol DQE = PORTA.4 : TRISA.4 = 1
    ' Symbol DQF = PORTA.5 : TRISA.5 = 0


    SerOut TXD,16468,[ "inicio das rotinas",10,13]
    delayms 500

    '
    ' Interface to a MAX31865 chip
    ' Written by Les Johnson for the Proton BASIC compiler
    '
    ' Include "Amicus18.inc" ' Configure the compiler to use a PIC18F25K20 device at 64MHz. i.e. an Amicus18 board



    $define cSensor_Wires 2 ' PT100/1000 has 2 or 3 or 4 wire connection
    $define MAX31865_SDO_Pin PORTA.1 'DQB ' Connects to the MAX31865 SDO pin
    $define MAX31865_SDI_Pin PORTA.0 'DQC ' Connects to the MAX31865 SDI pin
    $define MAX31865_SCLK_Pin PORTA.2'DQA ' Connects to the MAX31865 SCLK pin
    $define MAX31865_CS_Pin PORTA.3 'DQD ' Connects to the MAX31865 CS pin
    ' Create variables
    '
    Dim MAX31865_bReg0 As Byte ' \
    Dim MAX31865_bReg1 As Byte ' |
    Dim MAX31865_bReg2 As Byte ' |
    Dim MAX31865_bReg3 As Byte ' | Hold the register values from the MAX31865 chip
    Dim MAX31865_bReg4 As Byte ' |
    Dim MAX31865_bReg5 As Byte ' |
    Dim MAX31865_bReg6 As Byte ' |
    Dim MAX31865_bReg7 As Byte ' /
    Dim MAX31865_bLoop As Byte ' The SPI loop counter
    Dim MAX31865_bData As Byte ' The SPI transfer variable
    DIM WREG AS BYTE
    '------------------------------------------------------------------------------------------------
    GoTo Main ' Jump over the subroutines


    '-----------------------------------------------------------------------------


    $define MAX31865_Enable() Low MAX31865_CS_Pin ' Enable the SPI interface
    $define MAX31865_Disable() High MAX31865_CS_Pin ' Disable the SPI interface


    '-----------------------------------------------------------------------------
    ' Transmit and receive one byte using SPI mode 3 protocol
    ' Input : WREG = 8-bit value to send
    ' : MAX31865_SCLK_Pin holds the Port.bit of the SPI Clock pin
    ' : MAX31865_SDI_Pin holds the Port.bit of the SPI Data out Pin
    ' Output : WREG = 8-Bit value received
    ' Notes : SCLK is idle-high, and bits are latched on SCLK rising
    '
    $define MAX31865_Com(pByteout) _SPI_Out3 pByteout


    _SPI_Out3 Macro pByteout \Byte
    #if(Prm_Count >= 1)
    #if((Prm_1 == Num8) || (Prm_1 == Num16) || (Prm_1 == Num32))
    Num_Wreg pByteout
    #else
    Byte_Wreg pByteout
    #endif
    #else
    WREG = 0
    #endif
    GoSub __SPI_Out3
    Return_WREG
    Endm


    __SPI_Out3:
    MAX31865_bData = WREG ' Transfer the WREG into MAX31865_bData
    For MAX31865_bLoop = 7 To 0 Step -1 ' Single byte SPI loop
    Low MAX31865_SCLK_Pin ' Pull SCLK low
    DelayMS 1
    MAX31865_SDI_Pin = MAX31865_bData.7 ' Put current outgoing bit on MAX31865_SDI_Pin
    MAX31865_bData = MAX31865_bData << 1 ' Shift next bit into MSB
    DelayMS 1
    Set MAX31865_SCLK_Pin ' Set SCLK high
    MAX31865_bData = MAX31865_bData | MAX31865_SDO_Pin ' Capture current bit on MAX31865_SDO_Pin
    DelayMS 1
    Next
    WREG = MAX31865_bData ' Transfer MAX31865_bData into WREG
    Return


    '------------------------------------------------------------------------------------------------
    ' Configure the Interface to the MAX31865
    ' Input : None
    ' Output : None
    ' Notes : None
    '
    $define MAX31865_Setup() GoSub _MAX31865_Setup


    _MAX31865_Setup:
    Low MAX31865_SCLK_Pin
    Output MAX31865_SDI_Pin
    Input MAX31865_SDO_Pin

    MAX31865_Enable()
    DelayMS 10
    MAX31865_Com($80) ' Point to the Configuration register ($00)
    $if CSensor_Wires = 2 ' Are we using a 2 wire sensor?
    MAX31865_Com(%11000010)
    $elseif cSensor_Wires = 3 ' Are we using a 3 wire sensor?
    MAX31865_Com(%11010010)
    $elseif cSensor_Wires = 4 ' Are we using a 4 wire sensor?
    MAX31865_Com(%11000010)
    $endif
    MAX31865_Disable()
    DelayMS 50
    Return


    '------------------------------------------------------------------------------------------------
    ' Read the registers from the MAX31865
    ' Input : None
    ' Output : MAX31865_bReg0, MAX31865_bReg1, MAX31865_bReg2, MAX31865_bReg3, MAX31865_bReg4, MAX31865_bReg5, MAX31865_bReg6, MAX31865_bReg7
    ' Notes : None
    '
    $define MAX31865_Read() GoSub _MAX31865_Read


    _MAX31865_Read:
    MAX31865_Enable()
    MAX31865_Com(0) ' Start reading from address 0
    MAX31865_bReg0 = MAX31865_Com(0) ' \
    MAX31865_bReg1 = MAX31865_Com(0) ' |
    MAX31865_bReg2 = MAX31865_Com(0) ' |
    MAX31865_bReg3 = MAX31865_Com(0) ' | Read all the 8 registers
    MAX31865_bReg4 = MAX31865_Com(0) ' |
    MAX31865_bReg5 = MAX31865_Com(0) ' |
    MAX31865_bReg6 = MAX31865_Com(0) ' |
    MAX31865_bReg7 = MAX31865_Com(0) ' /
    MAX31865_Disable()
    Return


    '------------------------------------------------------------------------------------------------
    ' Transmit the register values via USART1
    ' Input : MAX31865_bReg0 to MAX31865_bReg7
    ' Output : None
    ' Notes : None
    '
    $define Display_Registers() GoSub _Display_Registers


    _Display_Registers:
    SerOut TXD,16468,[ "----------------------------------------------",10,13]
    SerOut TXD,16468,[ "Register values:",10,13]
    SerOut TXD,16468,[ "Reg0: Configuration = ", IBin8 MAX31865_bReg0,10,13]
    SerOut TXD,16468,[ "Reg1: RTD MSBs = ", IHex MAX31865_bReg1,10,13]
    SerOut TXD,16468,[ "Reg2: RTD LSBs = ", IHex MAX31865_bReg2,10,13]
    SerOut TXD,16468,[ "Reg3: High Fault Treshold MSB = ", IHex MAX31865_bReg3,10,13]
    SerOut TXD,16468,[ "Reg4: High Fault Treshold LSB = ", IHex MAX31865_bReg4,10,13]
    SerOut TXD,16468,[ "Reg5: Low Fault Treshold MSB = ", IHex MAX31865_bReg5,10,13 ]
    SerOut TXD,16468,[ "Reg6: Low Fault Treshold LSB = ", IHex MAX31865_bReg6,10,13]
    SerOut TXD,16468,[ "Reg7: Fault Status = ", IBin8 MAX31865_bReg7,10,13]
    return

    '------------------------------------------------------------------------------------------------
    ' The main program loop starts here
    '
    Main:
    MAX31865_Setup() ' Setup the interface to the chip


    Do
    MAX31865_Read() ' Read all 8 registers
    Display_Registers() ' Serially transmit the register values
    DelayMS 1000
    Loop

    Serial returned:
    ----------------------------------------------<LF><CR>
    Register values:<LF><CR>
    Reg0: Configuration = %10010001<LF><CR>
    Reg1: RTD MSBs = $0<LF><CR>
    Reg2: RTD LSBs = $0<LF><CR>
    Reg3: High Fault Treshold MSB = $FF<LF><CR>
    Reg4: High Fault Treshold LSB = $FF<LF><CR>
    Reg5: Low Fault Treshold MSB = $FF<LF><CR>
    Reg6: Low Fault Treshold LSB = $FF<LF><CR>
    Reg7: Fault Status = %00000000<LF><CR>
    ----------------------------------------------<LF><CR

  • Attention

    This valuable resource relies upon the very small amount of revenue generated by displaying online advertisements to our visitors.

    The advertisements we display are relevant to this web site and your browsing history

    Please consider supporting us by disabling your ad blocker.


    Note: Some users have reported issues related to ad-blockers rendering parts of this wesite unusable,
    where possible we will rectify the issues to enable you to use this resource with adblocking enabled.

    If you can, please report issues in the forum area WebSite / Forum Issues


    Thank you for your attention.

  • #6
    Fanatical Contributor top204's Avatar
    Join Date
    Feb 2002
    Posts
    3,481
    Thumbs Up
    Received: 315
    Given: 146
    Total Downloaded
    1.99 GB

    0 Not allowed!

    Default Re: Max31865 HELP ME

    The above program is written for more modern devices, such as 18F or enhanced 14-bit core types. These have access to the WREG as an SFR. The old standard 14-bit core devices do not, and this is where the problem lies.

    The difference is only in the SPI interface routine "MAX31865_Com", so here's one that will work on any device. replace the MAX31865_Com with this routine:

    Code:
    '-----------------------------------------------------------------------------
    ' Transmit and receive one byte using SPI mode 3 protocol
    ' Input     : MAX31865_bData = 8-bit value to send
    '           : MAX31865_SCLK_Pin holds the Port.bit of the SPI Clock pin
    '           : MAX31865_SDI_Pin holds the Port.bit of the SPI Data out Pin
    ' Output    : MAX31865_bData = 8-Bit value received
    ' Notes     : SCLK is idle-high, and bits are latched on SCLK rising
    '
    $define MAX31865_Com(pByteout) _SPI_Out3 pByteout
    
    _SPI_Out3 Macro pByteout \Byte
        #if(Prm_Count >= 1)
            #if((Prm_1 == Num8) || (Prm_1 == Num16) || (Prm_1 == Num32))
                Num_Byte pByteout, MAX31865_bData
            #else
                Byte_Byte pByteout, MAX31865_bData
            #endif
        #else
            MAX31865_bData = 0
        #endif
        GoSub __SPI_Out3
        Return_Byte MAX31865_bData
    Endm
    
    __SPI_Out3:
        For MAX31865_bLoop = 7 To  0  Step - 1              ' Single byte SPI loop
            Low MAX31865_SCLK_Pin                       ' Set SCLK low
            DelayMS  1 
            MAX31865_SDI_Pin = MAX31865_bData. 7          ' Put current outgoing bit on MAX31865_SDI_Pin
            MAX31865_bData = MAX31865_bData <<  1         ' Shift next bit into MSB
            DelayMS  1 
            High MAX31865_SCLK_Pin                       ' Set SCLK high
            MAX31865_bData = MAX31865_bData | MAX31865_SDO_Pin  ' Capture current bit on MAX31865_SDO_Pin
            DelayMS  1 
        Next
        Return

  • Attention

    This valuable resource relies upon the very small amount of revenue generated by displaying online advertisements to our visitors.

    The advertisements we display are relevant to this web site and your browsing history

    Please consider supporting us by disabling your ad blocker.


    Note: Some users have reported issues related to ad-blockers rendering parts of this wesite unusable,
    where possible we will rectify the issues to enable you to use this resource with adblocking enabled.

    If you can, please report issues in the forum area WebSite / Forum Issues


    Thank you for your attention.

    Thread Information

    Users Browsing this Thread

    There are currently 1 users browsing this thread. (0 members and 1 guests)

       

    Similar Threads

    1. Some example code for the max31865 RTC converter
      By Tim in forum Proton Plus Compiler v3
      Replies: 0
      Last Post: 20th August 2018, 09:39
    2. Max31865
      By Tim in forum Proton Plus Compiler v3
      Replies: 13
      Last Post: 27th November 2015, 09:19

    Tags for this Thread

    Posting Permissions

    • You may not post new threads
    • You may not post replies
    • You may not post attachments
    • You may not edit your posts